Reversed Labouchere system in roulette extreme analysed

The Reversed Labouchere is a cross-out system that begins with a list containing an arbitrary sequence of numbers such as 1,2,3,4. It is essentially a Labouchere system in reverse

The next bet is determined by adding the first and last numbers in the list. When the bet wins, the win amount is added to the end of the list. When the bet losses, the first and last numbers are crossed out (zeroed out for the System’s purpose).

The system was made famous in the book Thirteen Against the Bank: The True Story of How a Roulette Team Broke the Bank with an Unbeatable System.

Thirteen Against the Bank is a wry and detailed account of a true event that all expert opinion deemed impossible: beating the bank at roulette. It reveals how Leigh assembled and bankrolled his crew of thirteen, instilling in them the discipline and stamina to bring off this coup and then apply it using a system known as the Reverse Labouchere betting

Let’s work through an example. In the default system, the progression is just 1,2,3,4

Bet LineUnits StakedResultGain/ Loss
1-2-3-45lose-5
2-35lose-10
1-2-3-45win-5
1-2-3-4-56loss-11
2-3-46loss-17
33win-14
3-36win-8
3-3-69win+1
3-3-6-912win+13
3-3-6-9-1215win+28
3-3-6-9-12-1518win+46

So with the progression 1,2,3,4 the first bet is 5.  In this example, it lost.

The bet line becomes 2,3 and so the next bet is 5 again.

As that lost the progression goes back to 1,2,3,4, the next bet is 5.

That won so the progression becomes 1,2,3,4,5 and the next bet is 6

And so on.

You can see more in the video below

 

The system loses slowly with the odd winning streak.

 

It’s just the exact opposite of the Labouchere system, hence the name Reverse Labouchere! I can see why Norman Leigh used it. Slow losses followed by big wins.

 

                    
system "Reversed_Labouchere_System"

{The Reversed Labouchere is a cross-out system which begins with a list containing an
arbitrary sequence of numbers such as 1,2,3,4.

It is essentially a Labouchere system in reverse

The next bet is determined by adding the first and last numbers in the list.
When the bet wins, the win amount is added to the end of the list.
When the bet losses, the first and last numbers are crossed-out
(zeroed out for the System's purpose)

User selects which Even Money layout to use at the Start of a New Session
}
method "main"
begin
    While Starting a New Session
    begin
        Clear record "Progression list" data;
        Clear record "Pointer" data;
        Clear record "Net Bet to place" data;
        Call "Setup Layout";
        Call "Maximum Bet Allowed";
        call "Reset";
        call "Figure next bet";
        call "Make Bet";
        exit;
    end

    While record "Current Layout to Bet" layout has lost each time
    begin
        Put 1 on record "Progression list" Data index;
        Put 0 on record "Progression list" data;
        put 100% of record "Pointer" data to
                        record "Progression list" data index;
        Put 0 on record "Progression list" data;
    end

    While record "Current Layout to Bet" layout has won each time
    begin
        Add 1 on record "Pointer" data;
        put 100% of record "Pointer" data to
                        record "Progression list" data index;
        Put 100 % of the last record "Current Layout to Bet" layout on
                                                          record "Progression list" data;
    end

    Put 1 on record "Progression list" Data index;

    If record "Progression list" data = 0
    begin
        Move List Up by 1 to Record "Progression list" Data;
        Subtract 2 from Record "Pointer" Data;
        Put 1 on record "Progression list" Data index;
    end

    If record "Progression list" data = 0
    begin
        //Progression has won. Start Over
        call "Reset";
    end

    call "Figure next bet";
    
    while record "Net Bet to place" data > record "Maximum Bet" data
    begin
        Display "Maximum Bet has been Reached. Progression will start over.";
        call "Reset";
        call "Figure next bet";
    end
    
    call "Make Bet";
end

method "Reset"
begin
    Set List [1,2,3,4] on record "Progression list" data;
    Put 4 on record "Pointer" data;
    Put 1 on record "Progression list" Data index;
end

method "Figure next bet"
begin
    Put 1 on record "Progression list" Data index;
    Put 100 % of record "Progression list" data on record "Net Bet to place" Data;

    While Record "Pointer" data > 1
    begin
        put 100% of record "Pointer" data to
                        record "Progression list" data index;
        Add 100 % of record "Progression list" data on record "Net Bet to place" Data;
    end
end

method "Make Bet"
begin
    Put 100% of record "Net Bet to place" data on record "Current Layout to Bet" layout;
end

method "Setup Layout"
begin
    Input Dropdown "Make a Layout Selection

              1:=Even
              2:=Odd
              3:=Red
              4:=Black
              5:=High (19-36)
              6:=Low (1-18)" to Record "Layout Selection" data;

    If Record "Layout Selection" data = 1
    begin
        Copy Even to the Record "Current Layout to Bet" layout;
    end
    Else
    begin
        If Record "Layout Selection" data = 2
        begin
            Copy Odd to the Record "Current Layout to Bet" layout;
        end
        Else
        begin
            If Record "Layout Selection" data = 3
            begin
                Copy Red to the Record "Current Layout to Bet" layout;
            end
            Else
            begin
                If Record "Layout Selection" data = 4
                begin
                    Copy Black to the Record "Current Layout to Bet" layout;
                end
                Else
                begin
                    If Record "Layout Selection" data = 5
                    begin
                        Copy High to the Record "Current Layout to Bet" layout;
                    end
                    Else
                    begin
                        If Record "Layout Selection" data = 6
                        begin
                            Copy Low to the Record "Current Layout to Bet" layout;
                        end
                    end
                end
            end
        end
    end
end

method "Maximum Bet Allowed"
begin
    Set Flag "Input Ok" to False;
    
    Loop Until Flag "Input Ok" is True
    begin
        input data "Enter the Maximum bet Allowed.

                    Once Maximum Bet is reached, the
                    Progression will start over."
                    to record "Maximum Bet" data;

        if record "Maximum Bet" data < 6 then
        begin
            Display "Maximum Bet Must be Greater than Minimum Bet of 5 units.";
        end
        else
        begin
            Set Flag "Input Ok" to True;
        end
    end
end